OUTPUT_FORMAT ("elf32-littlearm","elf32-bigarm","elf32-littlearm")
ENTRY(_start)


MEMORY
{
  INTERRUPT	         (rwx) : ORIGIN = 0x80000000,    LENGTH = 1K
  DDR_cachedShared   (rwx) : ORIGIN = 0x80000400,  LENGTH = 64M
  DDR_region   (rwx) : ORIGIN = 0x84000400,  LENGTH = 64M
  DDR_reserved       (rwx) : ORIGIN = 0x90000000,  LENGTH = 256M
}

SECTIONS
{

/*
 .interrupt :
 {
	*interrupt.o (.text);
 } > INTERRUPT
 
 .tlb_table :
 {
	*mmu_tables.o (.data);
 } > DDR_cachedShared
*/
 
 .start :
 {
	 *startup.o (.text);
 } > DDR_cachedShared
 
 .text : ALIGN (8)
 {
	__pgm_load_start = LOADADDR (.text);
	__pgm_start = .;
	*(.text)
	*(.rodata)
	pgm_end = .;
	. = ALIGN (4); 
	__pgm_end = .; 
   } > DDR_cachedShared
  
 .data : ALIGN (8)
 {
	__data_load_start = LOADADDR (.data);
	__data_start = .;
	*(.data)
  data_end = .;
	. = ALIGN (4); 
    __data_end = .; 
 } > DDR_cachedShared
 
 .bss : ALIGN (8)
 {
  *(.bss)
  *(COMMON)	
 } > DDR_cachedShared


 .reserved :
 {
 . = ALIGN(0x8); /* aligned the heap on a 8 bytes boundary */
 heap_low = .; /* for _sbrk */
 . = . + 0x8000000; /* 128MB of heap memory */
 heap_top = .; /* for _sbrk */
 . = . + 0x8000000; /* 128MB of stack memory */
 . = ALIGN(0x8); /* aligned the stack on a 8 bytes boundary */
 stack_top = .; /* for startup.S */
 } > DDR_reserved

  .stab 0 (NOLOAD) : { *(.stab) }
  .stabstr 0 (NOLOAD) : { *(.stabstr) }
  /* DWARF debug sections.
   * Symbols in the DWARF debugging sections are relative to
   * the beginning of the section so we begin them at 0.
   */
  /* DWARF 1 */
  .debug          0 : { *(.debug) }
  .line           0 : { *(.line) }
  /* GNU DWARF 1 extensions */
  .debug_srcinfo  0 : { *(.debug_srcinfo) }
  .debug_sfnames  0 : { *(.debug_sfnames) }
  /* DWARF 1.1 and DWARF 2 */
  .debug_aranges  0 : { *(.debug_aranges) }
  .debug_pubnames 0 : { *(.debug_pubnames) }
  /* DWARF 2 */
  .debug_info     0 : { *(.debug_info .gnu.linkonce.wi.*) }
  .debug_abbrev   0 : { *(.debug_abbrev) }
  .debug_line     0 : { *(.debug_line) }
  .debug_frame    0 : { *(.debug_frame) }
  .debug_str      0 : { *(.debug_str) }
  .debug_loc      0 : { *(.debug_loc) }
  .debug_macinfo  0 : { *(.debug_macinfo) }
  /* DWARF 2.1 */
  .debug_ranges   0 : { *(.debug_ranges) }
  /* SGI/MIPS DWARF 2 extensions */
  .debug_weaknames 0 : { *(.debug_weaknames) }
  .debug_funcnames 0 : { *(.debug_funcnames) }
  .debug_typenames 0 : { *(.debug_typenames) }
  .debug_varnames  0 : { *(.debug_varnames) }

  .note.gnu.arm.ident 0 : { KEEP (*(.note.gnu.arm.ident)) }
.ARM.attributes 0 : { KEEP (*(.ARM.attributes)) }
}