@REM ******************************************************************
@REM * FILE PURPOSE: Environment Setup
@REM ******************************************************************
@REM * FILE NAME: mmwave_sdk_setupenv.bat
@REM *
@REM * DESCRIPTION:
@REM *  Configures and sets up the Build Environment for mmWave SDK.
@REM *
@REM ******************************************************************
@echo off

REM -------------------------------------------------------------------
REM Sanity Check: Ensure that all the required variables are defined
REM -------------------------------------------------------------------
if [%R4F_CODEGEN_INSTALL_PATH%] == [] (
@echo Error: R4F_CODEGEN_INSTALL_PATH [R4F Toochain] needs to be defined
@echo For Example:
@echo   set R4F_CODEGEN_INSTALL_PATH=C:/ti/ccsv6/tools/compiler/arm_15.12.3.LTS
goto fail
)
if [%MMWAVE_SDK_INSTALL_PATH%] == [] (
@echo Error: MMWAVE_SDK_INSTALL_PATH [mmWave SDK Package Location] needs to be defined
@echo For Example:
@echo   set MMWAVE_SDK_INSTALL_PATH=C:/ti/mmwave_sdk_01_00_00_00/packages
goto fail
)
if [%BIOS_INSTALL_PATH%] == [] (
@echo Error: BIOS_INSTALL_PATH [SYSBIOS] needs to be defined
@echo For Example:
@echo   set BIOS_INSTALL_PATH=c:/ti/bios_6_46_00_12_eng/packages
goto fail
)
if [%XDC_INSTALL_PATH%] == [] (
@echo Error: XDC_INSTALL_PATH [XDC Build Tools] needs to be defined
@echo For Example:
@echo   set XDC_INSTALL_PATH=c:/ti/xdctools_3_31_02_38_core
goto fail
)
if [%PERL_INSTALL_PATH%] == [] (
@echo Error: PERL_INSTALL_PATH [Perl Install Path] needs to be defined
@echo For Example:
@echo   set PERL_INSTALL_PATH=C:/Perl/Bin
goto fail
)
if [%DOWNLOAD_FROM_CCS%] == [] (
@echo Error: DOWNLOAD_FROM_CCS needs to be defined
@echo For Example:
@echo   set DOWNLOAD_FROM_CCS=yes
@echo   OR
@echo   set DOWNLOAD_FROM_CCS=no
goto fail
)
if [%MMWAVE_SDK_DEVICE%] == [] (
@echo Error: MMWAVE_SDK_DEVICE needs to be defined
@echo For Example:
@echo   set MMWAVE_SDK_DEVICE=awr14xx
@echo   OR
@echo   set MMWAVE_SDK_DEVICE=awr16xx
@echo   OR
@echo   set MMWAVE_SDK_DEVICE=iwr14xx
@echo   OR
@echo   set MMWAVE_SDK_DEVICE=iwr16xx
goto fail
)

set MMWAVE_SDK_DEVICE_TYPE=xwr14xx
if [%MMWAVE_SDK_DEVICE%] == [awr16xx] (
    set MMWAVE_SDK_DEVICE_TYPE=xwr16xx
)
if [%MMWAVE_SDK_DEVICE%] == [iwr16xx] (
    set MMWAVE_SDK_DEVICE_TYPE=xwr16xx
)

if [%MMWAVE_SDK_DEVICE_TYPE%] == [xwr16xx] (
if [%C674_CODEGEN_INSTALL_PATH%] == [] (
@echo Error: C674_CODEGEN_INSTALL_PATH [DSP Toolchain] needs to be defined
@echo For Example:
@echo   set C674_CODEGEN_INSTALL_PATH=C:/ti/ccsv6/tools/compiler/c6000_7.4.16
goto fail
)
if [%C64Px_DSPLIB_INSTALL_PATH%] == [] (
@echo Error: C64Px_DSPLIB_INSTALL_PATH needs to be defined
@echo For Example:
@echo   set C64Px_DSPLIB_INSTALL_PATH=C:/ti/dsplib_c64Px_3_4_0_0
goto fail
)
if [%C674x_MATHLIB_INSTALL_PATH%] == [] (
@echo Error: C674x_MATHLIB_INSTALL_PATH needs to be defined
@echo For Example:
@echo   set C674x_MATHLIB_INSTALL_PATH=C:/ti/mathlib_c674x_3_1_2_1
goto fail
)
if [%XWR16XX_RADARSS_IMAGE_BIN%] == [] (
@echo Error: XWR16XX_RADARSS_IMAGE_BIN needs to be defined with the complete path and filename of the BSS binary
@echo For Example:
@echo   set XWR16XX_RADARSS_IMAGE_BIN=%MMWAVE_SDK_INSTALL_PATH%/firmware/radarss/xwr16xx_radarss_rprc.bin
goto fail
)
if NOT EXIST "%XWR16XX_RADARSS_IMAGE_BIN%" (
@echo Error: %XWR16XX_RADARSS_IMAGE_BIN% does not exist. Check the path
goto fail
)
)

REM ----------------------------------------------------------
REM Setup the PATH configuration:
REM  This can be modified if the tools are installed in a
REM  different directory.
REM ----------------------------------------------------------

REM Clear all environment paths first.
REM set PATH=
set INCLUDE=
set LIB=

REM Test requirements
REM set PATH=%PATH%;C:/Windows;C:/Windows/system32

REM ----------------------------------------------------------
REM Please do not change anything below this
REM ----------------------------------------------------------

REM XDC Tools including gmake
set PATH=%PERL_INSTALL_PATH%;%XDC_INSTALL_PATH%;%XDC_INSTALL_PATH%/bin;%PATH%

REM Set XDC environment variables
set XDCCGROOT=%C674_CODEGEN_INSTALL_PATH%
set XDCBUILDCFG=%MMWAVE_SDK_INSTALL_PATH%/config.bld
set XDCARGS=

REM Clear all XDCPATH values first.
set XDCPATH=%BIOS_INSTALL_PATH%
set XDCPATH=%XDCPATH%;%MMWAVE_SDK_INSTALL_PATH%

REM TI Code Generation Tools
set PATH=%C674_CODEGEN_INSTALL_PATH%/bin;%PATH%
set PATH=%R4F_CODEGEN_INSTALL_PATH%/bin;%PATH%

REM Tools:
REM - Doxygen
REM These are only used by the release scripts. Customers can build without these defined.
set PATH=%DOXYGEN_INSTALL_PATH%\bin;%GRAPHVIZ_INSTALL_PATH%\bin;%PATH%

@echo -----------------------------------------------
@echo mmWave Build Environment Configured
@echo -----------------------------------------------

REM Set the Title Window appropriately.
Title mmWave Build Environment
goto end

:fail
@echo Error: Failed to setup mmWave Build Environment !
Title Error: Failed to setup mmWave Build Environment
REM Return error
EXIT /B 1

:end
REM Return success
EXIT /B 0