;========================================================================
; Setup CPU

SYStem.RESet
SYStem.CPU TMS570LS3137-ZWT
SYStem.JtagClock CTCK 25MHz
SYStem.MemAccess DAP
ETM.OFF
SYStem.Up

;========================================================================
; Flash declaration

FLASH.RESet

; Program flash
FLASH.Create  1. 0x000A0000--0x0017FFFF 0x20000 TARGET Byte 0.  ; Bank 0
FLASH.Create  2. 0x00180000--0x002FFFFF 0x20000 TARGET Byte 1.  ; Bank 1

; use flash algorithm with automatic ECC generation
FLASH.TARGET 0x08000000 0x08001000 0x4000 ~~/demo/arm/flash/byte_be/f021r4.bin

FLASH.CLocK auto

;========================================================================
; Flash programming

DIALOG.YESNO "Program application to flash memory?"
LOCAL &progflash
ENTRY &progflash

IF &progflash 
(
    FLASH.ReProgram 0x000A0000--0x002FFFFF /Erase
    Data.LOAD.auto .\build\main.hex
    FLASH.ReProgram off

    Print "Application flashed..."
)
;========================================================================
; load application symbols
Print "Loading Application symbols..."
Data.LOAD.auto .\build\main.out /noCODE

Print "Application symbols loaded..."

;========================================================================
; breakpoint configuration

; use onchip breakpoints
map.bonchip

;========================================================================
; setup view

; Switch to high level view (only C, no assemler code)
Mode.HLL

; Set format of data values to hex and decimal
setup.var %Decimal %E

;========================================================================
; setup window configuration

DIALOG.YESNO "reset window configuration?"
entry &reswin
if &reswin
(
    TOOLBAR ON
    STATUSBAR ON
    FramePOS 28.125,16.071,,,Maximized
    WinPAGE.RESet
    
    WinPAGE.Create P000
    
    WinCLEAR
    WinPOS 103.63 0.0 52. 29. 0. 0. W001
    Register /Spotlight
    
    WinPOS 0.0 0.0 99. 44. 13. 1. W000
    WinTABS 10. 10. 25. 62.
    Data.List
    
    WinPOS 103.5 33.143 52. 23. 0. 1. W002
    WinTABS 21. 21.
    sYmbol.Browse.Function
 
    WinPOS 160.25 0.0 75. 49. 0. 0. W004
    Var.Watch
 
    WinPOS 160.25 54.571 77. 5. 10. 1. W005
    rt
    
    WinPOS 0.0 49.643 99. 7. 23. 1. W003
    WinTABS 0. 0. 0. 0. 0. 0. 0.
    Break.List
 
    WinPAGE.select P000
)

; Add reset toolbar
menu.REPROGRAM "bsp\toolbar.men"
  
;======================
;===  end of script ===
;======================

ENDDO