MEMORY
{

PAGE 0 :    // Program memory

    // BEGIN is used for the "boot to SARAM" bootloader mode
    BEGIN       : origin = 0x000000, length = 0x000002

    // RAMMx is MCU dedicated, 2048 bytes each, 4096 total
    RAMM0       : origin = 0x000122, length = 0x0002DE

    // RAMDx is MCU dedicated, 4096 bytes each, 8192 total
    RAMD0       : origin = 0x00B000, length = 0x000800

    // RAMLSx can be shared with CLA via MSEL_LSx bit field, 4096 bytes each, 24,576 total
    RAMLS0      : origin = 0x008000, length = 0x000800
    RAMLS1      : origin = 0x008800, length = 0x000800
    RAMLS2      : origin = 0x009000, length = 0x000800
    RAMLS3      : origin = 0x009800, length = 0x000800
    RAMLS4      : origin = 0x00A000, length = 0x000800

    // Reset
    RESET       : origin = 0x3FFFC0, length = 0x000002

    // On-chip flash sectors
    FLASHA      : origin = 0x080000, length = 0x002000
    FLASHB      : origin = 0x082000, length = 0x002000
    FLASHC      : origin = 0x084000, length = 0x002000
    FLASHD      : origin = 0x086000, length = 0x002000
    FLASHE      : origin = 0x088000, length = 0x002000
    FLASHF      : origin = 0x090000, length = 0x002000
    FLASHG      : origin = 0x098000, length = 0x002000
    FLASHH      : origin = 0x0A0000, length = 0x002000
    FLASHI      : origin = 0x0A8000, length = 0x002000
    FLASHJ      : origin = 0x0B0000, length = 0x002000
    FLASHK      : origin = 0x0B8000, length = 0x002000
    FLASHL      : origin = 0x0BA000, length = 0x002000
    FLASHM      : origin = 0x0BC000, length = 0x002000
    FLASHN      : origin = 0x0BE000, length = 0x002000

// Not used

    // Vector table
//    PIEVECTTABLE    :origin = 0x000D00, length = 0x000200

    // CLA messaging
//    CLA1_MSGRAMLOW  : origin = 0x001480, length = 0x000080
//    CLA1_MSGRAMHIGH : origin = 0x001500, length = 0x000080

    // UP RX/TX messaging
//    UPPTXMSG        : origin = 0x006C00, length = 0x000200
//    UPPRXMSG        : origin = 0x006E00, length = 0x000200

    // Secure ROM
//    SECUREROM   :origin = 0x3F0000, length = 0x008000

    // Boot ROM
//    BOOTROM     :origin = 0x3F8000, length = 0x007FC0

// End - Not used

PAGE 1 :    // Data memory

    // Part of M0, BOOT rom will use this for the stack
    BOOT_RSVD   : origin = 0x000002, length = 0x000120

    // RAMMx is MCU dedicated, 2048 bytes each, 4096 total
    RAMM1       : origin = 0x000400, length = 0x000400

    // RAMDx is MCU dedicated, 4096 bytes each, 8192 total
    RAMD1       : origin = 0x00B800, length = 0x000800

    // RAMLSx can be shared with CLA via MSEL_LSx bit field, 4096 bytes each, 24,576 total
    RAMLS5      : origin = 0x00A800, length = 0x000800

    // RAMGSn Globaly shared between MCUs, 8192 bytes each, 131,072 total
    RAMGS0      : origin = 0x00C000, length = 0x001000
    RAMGS1      : origin = 0x00D000, length = 0x001000
    RAMGS2      : origin = 0x00E000, length = 0x001000
    RAMGS3      : origin = 0x00F000, length = 0x001000
    RAMGS4      : origin = 0x010000, length = 0x001000
    RAMGS5      : origin = 0x011000, length = 0x001000
    RAMGS6      : origin = 0x012000, length = 0x001000
    RAMGS7      : origin = 0x013000, length = 0x001000
    RAMGS8      : origin = 0x014000, length = 0x001000
    RAMGS9      : origin = 0x015000, length = 0x001000
    RAMGS10     : origin = 0x016000, length = 0x001000
    RAMGS11     : origin = 0x017000, length = 0x001000
    RAMGS12     : origin = 0x018000, length = 0x001000
    RAMGS13     : origin = 0x019000, length = 0x001000
    RAMGS14     : origin = 0x01A000, length = 0x001000
    RAMGS15     : origin = 0x01B000, length = 0x001000

    // MCU shared
    CPU2TOCPU1RAM   : origin = 0x03F800, length = 0x000400
    CPU1TOCPU2RAM   : origin = 0x03FC00, length = 0x000400

// Not used

    // CAN messaging
//    CANA_MSG_RAM    : origin = 0x049000, length = 0x000800
//    CANB_MSG_RAM    : origin = 0x04B000, length = 0x000800

// End - Not used
}

SECTIONS
{
    // Code start entry point
    codestart   : > BEGIN, PAGE = 0

    // Initialized C global variables at startup
    .cinit      : > RAMM0, PAGE = 0

    // Stdio buffer
    .cio        : > RAMLS2, PAGE = 0

    // Initialized non-const global data
    .data       : > RAMGS4, PAGE = 1

    // Reserve space for unintiliazed variables
    .ebss       : > RAMLS5, PAGE = 1

    // Initialized const objects
    .econst     : > RAMLS5, PAGE = 1

    // Dynamic memory allocation
    .esysmem    : > RAMLS5, PAGE = 1

    // C++ startup constructor tables
    .pinit      : > RAMM0, PAGE = 0

    // Reset
    .reset      : > RESET, PAGE = 0, TYPE = DSECT // not used

    // Function call stack, cio (printf) requires a larger stack
    .stack      : > RAMGS2, PAGE = 1

    // Jump tables for switch statements
    .switch     : > RAMM0, PAGE = 0

    // Executable code
    .text       : >> RAMM0 | RAMD0 | RAMLS0 | RAMLS1, PAGE = 0

// Not used or deprecated

    // Boot-time copy tables (.binit)
    // Uninitialized global variables (.bss)
    // Initialized global variables (.const)

// End - Not used or deprecated

#ifdef __TI_COMPILER_VERSION__
    #if __TI_COMPILER_VERSION__ >= 15009000
    .TI.ramfunc : {} > RAMM0,   PAGE = 0
   #else
    ramfuncs    : > RAMM0,      PAGE = 0
   #endif
#endif

}

//===========================================================================
//    End of file.
//===========================================================================