Simulation in Spice OrCAD

Karim,

We would need much more information to help in this case. A quick Google search on your errors leads me to believe that your are trying to use a subcircuit in PSpice that is not compatible with PSpice. Without the .SUBCKT or the circuit your are using, I do not believe that we can help. What device are you using? What version of PSpice are you using? What are you trying to simulate? What is the circuit to be used for?

This information may help us to determine the cause of the errors you are seeing.

Britt

The following error usually comes when you are doing a DC sweep and the sweep parameter is not increasing or decreasing monotonically.

Values must be monotonic increasing

thank you very much Britt   and Nikhil Gupta

 I simulate a model of a MOS transistor in OrCAD Capture Spice 16.5  and I want to simulate the transient of the circuit. So here is all the script circuit:

* source EX10
V_V6 V1 0 24
V_V8 N232814 0
+PWL 0 -4.6 460n -4.6 503n 13.4 616n 13.4 2395n 13.4 2445n 2 2500n -4.6 5000n
+ -4.6
V_V11 N232762 0 24
X_U1 V1 N232814 0 N232762 0 MOS7

.tran 0.1ms 0.2s 0s

.SUBCKT MOS7 D G S T TC
R1 G A 1
C1 A B {GMUX*MIC1*10^-12}
C2 E A {GMUX*MIC2*10^-12}
C3 A J {GMUX*MIC3*10^-12}
R4 E N 1
E1 B J Value={V(A1,J)*V(C,J)}
E2 C J Table {V(N,J)}= (0,0) (MIC5,1)
R2 A J 1e6
R3 A A1 1k
C4 A1 J 1p
*
**Detecteur d'état du MOS **
E7 P 0 Table {V(N,J)} = (.1,0) (.2,1) ; mise en conduction
** Admittance d'entrée**
E3 K J Table {(MAD10+MAD11*V(T,0)+MAD12*V(T,0)^2+MAD20+MAD21*V(T,0)+MAD22*V(T,0)^2)*V(A1,J)} = (0,0) (100,100)
** le Canal Drain Source et ses parasites**
R5 D N .001
V1 N H 0
E4 H L Table {V(P,0)*(MRD10+MRD11*V(T,0)+(MRD20+MRD21*V(T,0))*I(V1)+(MRD30+MRD31*V(T,0))*I(V1)^2)}=(0,0) (50,50)
E5 L J Table {10000 * I(V1) - V(K,J)} = (0,0) (1400,1400)
R7 N J1 1
C6 J1 J {MIC4*10^-12}
R6 N F1 1k
C5 F1 J 2p
L1 J S .15n
RL1 J S .001
*
**Diode de conduction directe**
D1 J N Rclamp
.model RClamp D RS=1.4
*
**Reverse Current**
**N'est pas utilisé car dans les pires des cas = 3.3W
*G2 E J Value={0}
*RFJ F J 1e6
*
*
**Dissipation**
VTA TA 0 pwl (0,0) (1e-6,0) (2e-6,1)
VTB TB 0 pwl (0,1) (1e-6,1) (2e-6,0)
E6 Z 0 Value={V(N,J)*I(V1)}
R8 Z Y 2k
C7 Y 0 2p
G3 0 T Value={V(P,0)*V(TA,0)*V(Y,0)+(V(TB,0)*V(TC,0))}
*
** le Circuit Thermique**
RT1 T T1 {TR1}
CT1 T T1 {TC1}
RT2 T1 T2 {TR2}
CT2 T1 T2 {TC2}
RT3 T2 T3 {TR3}
CT3 T2 T3 {TC3}
RT4 T3 TC {TR4}
CT4 T3 TC {TC4}
*
**Models and Parameters**
*
**Les Parameters des capacitées **
.param MIC1=3.161e+003
.param MIC2=5.748e+001
.param MIC3=2.367e+003
.param MIC4=1.719e+002
.param MIC5=5.000e+001
.param GMUX=1
*
** Les paramètres de la tension directe RDS(on)**
.param MRD10= 5.881e-001 MRD11=-1.033e-003
.param MRD20=-1.147e+000 MRD21= 4.541e-003
.param MRD30=-1.334e-002 MRD31= 6.422e-005
*
**L'Admittance d'entrée**
.param MAD10=0.000e+000 MAD11=-9.331e-001 MAD12= 1.919e-003
.param MAD20=0.000e+000 MAD21= 1.765e-001 MAD22=-3.475e-004
*
**Les Parameters ducourant en inverse**
*
*
**Les Parametersdu modèle thermique**
.param TR1=2.889e-001 TC1=5.082e-001
.param TR2=9.876e-002 TC2=6.927e-002
.param TR3=6.745e-002 TC3=6.709e-003
.param TR4=5.344e-001 TC4=7.472e-006
*
.ENDS MOS7
******************************************************************

thank you very much Britt
the program works thank you very much
really you are a great man  thank you very much