SN74LVC1G126: SN74LVC1G126: PSpice model error: Values must be monotonic increasing

Hi Tim,

Are you sure you aren't using the PSpice Behavioral model? Pspice will not support HSpice models.

-

I assuming you are using the PSpice Behavioral model, as I know this is an issue with some of our models. If you open the .cir file and look towards the bottom of the code you will find this section (lines 186 to 204):

.SUBCKT LOGIC_TRI_STATE_OUTPUT_LVC_1i_AND_Tristate_CMOS_SN74LVC1G126 IN OUT OEZ VCC VEE
EROH NROH VEE TABLE {V(VCC,VEE)} = 
+(1.65,112.5) 
+(2.3,50) 
+(3,37.5) 
+(3,29.1666666666667) 
+(4.5,21.875) 
EROL NROL VEE TABLE {V(VCC,VEE)} = 
+(1.65,112.5) 
+(2.3,37.5) 
+(3,25) 
+(3,22.9166666666667) 
+(4.5,17.1875) 
EOEZ N2 VEE VALUE = {V(OEZ,VEE)} 
E1 N1 VEE VALUE = {V(VCC,VEE)*V(IN,VEE)*V(N2,VEE)} 
GOUT N1 OUT VALUE = {V(N1,OUT)*V(N2,VEE)*(V(IN,VEE)/V(NROH,VEE) + (1 - V(IN,VEE))/V(NROL,VEE))} 
LOUT N1 OUT .1n 
ROUT OUT VEE 1E8 
.ENDS 

The values in the EROH and EROL tables are incorrect -- you can see that there are two values for "3" which is causing the nonmonotonic error.

Additionally, the LOUT inductor should be commented out - it will cause issues with the simulation.

To fix the code, change it to the following:

.SUBCKT LOGIC_TRI_STATE_OUTPUT_LVC_1i_AND_Tristate_CMOS_SN74LVC1G126 IN OUT OEZ VCC VEE
EROH NROH VEE TABLE {V(VCC,VEE)} = 
+(1.65,112.5) 
+(2.3,50) 
+(3,33.3) 
+(4.5,21.875) 
EROL NROL VEE TABLE {V(VCC,VEE)} = 
+(1.65,112.5) 
+(2.3,37.5) 
+(3,24) 
+(4.5,17.1875) 
EOEZ N2 VEE VALUE = {V(OEZ,VEE)} 
E1 N1 VEE VALUE = {V(VCC,VEE)*V(IN,VEE)*V(N2,VEE)} 
GOUT N1 OUT VALUE = {V(N1,OUT)*V(N2,VEE)*(V(IN,VEE)/V(NROH,VEE) + (1 - V(IN,VEE))/V(NROL,VEE))} 
*LOUT N1 OUT .1n 
ROUT OUT VEE 1E8 
.ENDS 

Hello Emrys, 

      I am sorry, it is PSpice Behavioral model. After correct the value ,the model is available, thanks for your help.