This thread has been locked.

If you have a related question, please click the "Ask a related question" button in the top right corner. The newly created question will be automatically linked to this question.

  • Resolved

program will not fit into available .stack :(

Prodigy 160 points

Replies: 5

Views: 1746

I'm trying to compile a project on the C2000 Launchpad f28027.I'm getting a linker error:

warning #10210-D: creating ".esysmem" section with default size of 0x400; use the -heap option to change the default size
"../28027_RAM_lnk.cmd", line 127: error #10099-D: program will not fit into available memory.  run placement with alignment/blocking fails for section ".stack" size 0x300 page 1.  Available memory ranges:
   RAMM1        size: 0x400        unused: 0x0          max hole: 0x0  

I am creating a static object, however it should put it in the BSS?
I've already tried adjusting the stack size in Linker properties.
I appreciate any help :)

#include "SomeObject.h"
int main(void)
{
	static SomeObject foo;
    while(1)
    {
        if(foo.isReady())
        {
            foo.doWork();
        }
    }
}

/*
// TI File $Revision: /main/5 $
// Checkin $Date: July 6, 2009   17:18:44 $
//###########################################################################
//
// FILE:    28027_RAM_lnk.cmd
//
// TITLE:   Linker Command File For 28027 examples that run out of RAM
//
//          This ONLY includes all SARAM blocks on the 28027 device.
//          This does not include flash or OTP.
//
//          Keep in mind that L0 is protected by the code
//          security module.
//
//          What this means is in most cases you will want to move to
//          another memory map file which has more memory defined.
//
//###########################################################################
// $TI Release: DSP2802x Header Files Internal Release 2 $
// $Release Date: July 15, 2008 $
//###########################################################################
*/

/* ======================================================
// For Code Composer Studio V2.2 and later
// ---------------------------------------
// In addition to this memory linker command file,
// add the header linker command file directly to the project.
// The header linker command file is required to link the
// peripheral structures to the proper locations within
// the memory map.
//
// The header linker files are found in <base>\DSP2802x_headers\cmd
//
// For BIOS applications add:      DSP2802x_Headers_BIOS.cmd
// For nonBIOS applications add:   DSP2802x_Headers_nonBIOS.cmd
========================================================= */

/* ======================================================
// For Code Composer Studio prior to V2.2
// --------------------------------------
// 1) Use one of the following -l statements to include the
// header linker command file in the project. The header linker
// file is required to link the peripheral structures to the proper
// locations within the memory map                                    */

/* Uncomment this line to include file only for non-BIOS applications */
/* -l DSP2802x_Headers_nonBIOS.cmd */

/* Uncomment this line to include file only for BIOS applications */
/* -l DSP2802x_Headers_BIOS.cmd */

/* 2) In your project add the path to <base>\DSP2802x_headers\cmd to the
   library search path under project->build options, linker tab,
   library search path (-i).
/*========================================================= */

/* Define the memory block start/length for the DSP2802x
   PAGE 0 will be used to organize program sections
   PAGE 1 will be used to organize data sections

   Notes:
         Memory blocks on F28027 are uniform (ie same
         physical memory) in both PAGE 0 and PAGE 1.
         That is the same memory region should not be
         defined for both PAGE 0 and PAGE 1.
         Doing so will result in corruption of program
         and/or data.

         The L0 memory blocks is mirrored - that is
         it can be accessed in high memory or low memory.
         For simplicity only one instance is used in this
         linker file.

         Contiguous SARAM memory blocks can be combined
         if required to create a larger memory block.
*/

MEMORY
{
PAGE 0 :
   /* For this example, L0 is split between PAGE 0 and PAGE 1 */
   /* BEGIN is used for the "boot to SARAM" bootloader mode   */

   BEGIN      : origin = 0x000000, length = 0x000002
   RAMM0      : origin = 0x000050, length = 0x0003B0
   PRAML0     : origin = 0x008000, length = 0x000900
   RESET      : origin = 0x3FFFC0, length = 0x000002

   IQTABLES   : origin = 0x3FE000, length = 0x000B50     /* IQ Math Tables in Boot ROM */
   IQTABLES2  : origin = 0x3FEB50, length = 0x00008C     /* IQ Math Tables in Boot ROM */
   IQTABLES3  : origin = 0x3FEBDC, length = 0x0000AA	 /* IQ Math Tables in Boot ROM */

   BOOTROM    : origin = 0x3FF27C, length = 0x000D44


PAGE 1 :

   /* For this example, L0 is split between PAGE 0 and PAGE 1 */
   BOOT_RSVD   : origin = 0x000002, length = 0x00004E     /* Part of M0, BOOT rom will use this for stack */
   RAMM1       : origin = 0x000400, length = 0x000400     /* on-chip RAM block M1 */
   DRAML0      : origin = 0x008900, length = 0x000700
}


SECTIONS
{
   /* Setup for "boot to SARAM" mode:
      The codestart section (found in DSP28_CodeStartBranch.asm)
      re-directs execution to the start of user code.  */
   codestart        : > BEGIN,     PAGE = 0
   ramfuncs         : > RAMM0      PAGE = 0
   
#ifdef __TI_COMPILER_VERSION__
   #if __TI_COMPILER_VERSION__ >= 15009000
    .TI.ramfunc : {} > RAMM0,      PAGE = 0
   #endif
#endif   

   .text            : > PRAML0,    PAGE = 0
   .cinit           : > RAMM0,     PAGE = 0
   .pinit           : > RAMM0,     PAGE = 0
   .switch          : > RAMM0,     PAGE = 0
   .reset           : > RESET,     PAGE = 0, TYPE = DSECT /* not used, */

   .stack           : > RAMM1,     PAGE = 1
   .ebss            : > DRAML0,    PAGE = 1
   .econst          : > DRAML0,    PAGE = 1
   .esysmem         : > RAMM1,     PAGE = 1

   IQmath           : > PRAML0,    PAGE = 0
   IQmathTables     : > IQTABLES,  PAGE = 0, TYPE = NOLOAD

  /* Uncomment the section below if calling the IQNexp() or IQexp()
      functions from the IQMath.lib library in order to utilize the
      relevant IQ Math table in Boot ROM (This saves space and Boot ROM
      is 1 wait-state). If this section is not uncommented, IQmathTables2
      will be loaded into other memory (SARAM, Flash, etc.) and will take
      up space, but 0 wait-state is possible.
   */
   /*
   IQmathTables2    : > IQTABLES2, PAGE = 0, TYPE = NOLOAD
   {

              IQmath.lib<IQNexpTable.obj> (IQmathTablesRam)

   }
   */
   /* Uncomment the section below if calling the IQNasin() or IQasin()
      functions from the IQMath.lib library in order to utilize the
      relevant IQ Math table in Boot ROM (This saves space and Boot ROM
      is 1 wait-state). If this section is not uncommented, IQmathTables2
      will be loaded into other memory (SARAM, Flash, etc.) and will take
      up space, but 0 wait-state is possible.
   */
   /*
   IQmathTables3    : > IQTABLES3, PAGE = 0, TYPE = NOLOAD
   {

              IQmath.lib<IQNasinTable.obj> (IQmathTablesRam)

   }
   */

}

/*
//===========================================================================
// End of file.
//===========================================================================
*/


  • Hi,

    You can try increasing the stack & heap size by navigating to Project -> Properties -> Build -> C2000 Linker -> Basic Options

    Regards,
    Gautam

     

    If a post answers your question, please click on "This resolved my issue" button

    Are You A Beginner or New to TI's C2000™ Family? Do Check This Book!

  • In reply to Gautam Iyer:

    Hi Zach,

    The following may serve as a good reference:
    http://processors.wiki.ti.com/index.php/C28x_Compiler_-_Understanding_Linking


    Thank you,
    Brett

  • In reply to Gautam Iyer:

    I've increased both the stack and heap size to no avail.

    In fact, increasing the heap and stack made it worse.

    I increased the heap to 0x800 bytes and now the .esysmem section fails too.

  • In reply to Zach Wilcox:

    What you're likely going to need to do is allocate .esysmem to a ram block that isn't RAMM1 (but something also allocated to PAGE1).  DRAML0 may be feasible, depending on how utilized it already is.

    Doing this will enable RAMM1 to be used completely for stack.  And likely enable the linker to do its job.

    Another possibility is to move from the RAM linker command file you are currently using to a FLASH-based linker command file.  This will give you more memory to allocate to, most of which you'll likely use for program memory.

    Note that after linking, the linker generates a .map file which can help you understand your memory utilization.


    Thank you,
    Brett

  • In reply to Brett Larimore:

    Thanks.
    This got me going.
    I fixed it by changing the following:

    .esysmem         : > RAMM1,     PAGE = 1
    
    
    to
    .esysmem         : > RAMM1 | DRAML0,     PAGE = 1

    and correcting my heap size.

This thread has been locked.

If you have a related question, please click the "Ask a related question" button in the top right corner. The newly created question will be automatically linked to this question.