TMS320F280049: dslight problem

Hi Florian,

Will consult with the other experts on this issue and get back to you within the next few days.

Thanks and regards,

Charles

Hi Florian,

Are you able to check/open the dslite.bat file to see what the path is for the dslite.exe? The dslite.bat file sets the path which contains the executable.

Thanks and regards,

Charles

Hi Charles,

here is the complete batch file. I hope this is the information you need.

regards,

Florian

@echo off
setlocal
setlocal ENABLEDELAYEDEXPANSION

REM Path to this batch script
set SCRIPT_PATH=%~dp0

REM path to local user TICloudAgent
set DEBUGSERVER_ROOT=!SCRIPT_PATH!deskdb\content\TICloudAgent\win\ccs_base\DebugServer\

REM update PATH to include the TICloudAgent DS common bin
set PATH=%PATH%;!DEBUGSERVER_ROOT!..\common\bin\

REM default mode (flash,memory,cc3200,cc32xx) and executable
set MODE=flash
set EXECUTABLE="!DEBUGSERVER_ROOT!bin\DSLite"

if "%1"=="" (
	echo.
	echo Using default 'flash' mode. ^(Use --listMode option to view available modes and usage^)
	echo.
)

REM list available modes
if "%1"=="--listMode" (
	echo.
	
	echo Usage: dslite --mode ^<mode^> arg
	echo.
	
	echo Available Modes for UniFlash CLI:
	echo   * flash [default]		- on-chip flash programming
	echo   * memory			- export memory to a file
	echo   * load			- simple loader [use default options]
	echo   * cc13xx-cc26xx-mass-erase	- unlock a locked CC13xx/CC26xx device by performing a mass erase
if exist !SCRIPT_PATH!simplelink (
	echo   * cc31xx			- flashing SimpleLink CC31xx [imagecreator]
	echo   * cc32xx			- flashing SimpleLink CC32xx [imagecreator]
)
if exist !DEBUGSERVER_ROOT!drivers\MSP430Flasher.exe (
	echo   * mspflasher			- support MSPFlasher command line parameters [deprecated]
)
if exist !SCRIPT_PATH!processors\ProcessorSDKSerialFlash.exe (
	echo   * processors			- support ProcessorSDKSerialFlash command line parameters [Processor Serial Flash CLI Tool]
)
	exit /b 0
)

REM user options parsing
set USEROPTIONS=%*

REM user options without the --mode
set "_args=%*"
set "_args=!_args:*%1 =!"
set "_args=!_args:*%2 =!"

if "%3"=="" (
	set USEROPTIONS2=
) else (
	set USEROPTIONS2=!_args!
)

REM custom mode from users
if "%1" EQU "--mode" (
	set MODE=%2
	set USEROPTIONS=!USEROPTIONS2!
)

REM default user options if none given
if "!USEROPTIONS!" EQU "" (
	set USEROPTIONS=-h
)

REM SimpleLink (imagecreator) support
if "%MODE%" EQU "cc32xx" (
	cd /D !SCRIPT_PATH!simplelink\imagecreator\bin\
	set EXECUTABLE=!SCRIPT_PATH!simplelink\imagecreator\bin\SLImageCreator.exe
	set MODE=
)
if "%MODE%" EQU "cc31xx" (
	cd /D !SCRIPT_PATH!simplelink\imagecreator\bin\
	set EXECUTABLE=!SCRIPT_PATH!simplelink\imagecreator\bin\SLImageCreator.exe
	set MODE=
)

REM mspflasher support
if "%MODE%" EQU "mspflasher" (
	set EXECUTABLE=!DEBUGSERVER_ROOT!drivers\MSP430Flasher.exe
	set MODE=
)

REM ProcessorSDKSerialFlash support
if "%MODE%" EQU "processors" (
	cd /D !SCRIPT_PATH!processors\
	set EXECUTABLE=!SCRIPT_PATH!processors\ProcessorSDKSerialFlash.exe
	set MODE=
)

REM execute with given user parameters
echo Executing the following command:
if "!MODE!" EQU "" (
	echo ^> !EXECUTABLE! !USEROPTIONS!
) else (
	echo ^> !EXECUTABLE! !MODE! !USEROPTIONS!
)
echo.

echo For more details and examples, please refer to the UniFlash Quick Start guide.
echo.

CMD /S /C "%EXECUTABLE% !MODE! !USEROPTIONS!"
exit /b !errorlevel!

Hi Florian,

There is a redundant call to dslite.exe, remove the "dslite.exe flash" from the command line. Dslite.bat should be able to take care of this by itself.

Thanks,

Charles