Comparation between TI's TL431 Spice Model & Onsemi's TL431 Spice Model by Christophe Basso. Using these models in DC Analysis obtains two differnet plots in PSpice16.6.

TL431 Spice Model from TI is as follows

*****************************************************************************
* TL431 MACROMODEL 3-26-92
* REV N/A DBB
*****************************************************************************
*                 REFERENCE
*                 |  ANODE
*                 |  |  CATHODE
*                 |  |  |
.SUBCKT  TL431/TI 1  2  3
V1  6  7  DC  1.4V
I1  2  4  1E-3
R1  1  2  1.2E6
R2  4  2  RMOD 2.495E3
R3  5  7  .2
D1  3  6  DMOD1
D2  2  3  DMOD1
D3  2  7  DMOD2
E1  5  2  POLY(2)  (4,2)  (1,2)  0  710  -710
.MODEL RMOD RES (TC1=1.4E-5 TC2=-1E-6)
.MODEL DMOD1 D (RS=.3)
.MODEL DMOD2 D (RS=1E-6)
.ENDS



Onsemi's TL431 Spice Model by Christophe Basso is as follows

********
.SUBCKT TL431 k a ref
* made by Chris Basso - 2005
G1 a 2 5 ref -250u
Q1 k 2 1 QN3904
R1 1 7 240
R2 7 a 6.6k
Q2 k 7 a QN3904 50
D1 ref k DN4148
C2 7 a 1n
D2 a k D2_mod
C1 k 2 43p
V1 5 a DC=2.49
D3 a 2 D3_mod
.MODEL QN3904 NPN AF=1.0 BF=300 BR=7.5 CJC=3.5PF CJE=4.5PF
+ IKF=.025 IS=1.4E-14 ISE=3E-13 KF=9E-16 NE=1.5 RC=2.4
+ TF=4E-10 TR=21E-9 VAF=100 XTB=1.5
.MODEL DN4148 D BV=100V CJO=4PF IS=7E-09 M=.45 N=2 RS=.8
+ TT=6E-09 VJ=.6V
.MODEL D2_mod D BV=36 CJO=4PF IS=7E-09 M=.45 N=1.3 RS=.8
+ TT=6E-09 VJ=.6V
.MODEL D3_mod D N=0.01
.ENDS

Observing the two Spice models, we can find out that the spice model of TI is a very simple model, using "E" in pspice, and there's only a 1.2M ohm resistor connected to the teminal ref in addition to the "E" part.
Maybe TI has not considered the terminal ref should be stable at around 2.5V when the voltage signal teminated to the terminal ref is above or equal to 2.5V ???

Hello Jankel,

Yes, the TL431 models is a simple behavioral model in this case.

We will look further into this. Thank you for your feedback.

Best,
Michael