debugging problems with migration from CCS V5.3 to CCS V5.5

Andreas,

The likely cause of this is a change in CCSv5.5 related to flash programming.   The compiler that ships with CCSv5.5 can generate ECC data now, so we changed the setting in CCS to *not* auto-generate ECC on flash download.  This was probably a mistake in retrospect because of the confusion it is causing.

You probably just need to change this setting back.   I'm not at a place where I can open CCS at the moment to get a screenshot to show you how to do this, but hopefully you can find it in the CCS menus.  It's a checkbox on the tab that lets you manually erase the flash and that also lets you select whether you want to erase the whole flash or just the sectors that you need to use for the program you are about to load.

EDIT: 
Here's the option you probably need to check:

Best Regards,

Anthony

Andy,

ECC generation is controlled by the linker command file.

See http://www.ti.com/general/docs/lit/getliterature.tsp?baseLiteratureNumber=spnu118&fileType=pdf

Section 8.5.8 shows what goes in the command file.

There is also a compiler option to inject errors in select locations so that you can check the functionality of the ECC logic, which you can find in the compiler manual  http://www.ti.com/general/docs/lit/getliterature.tsp?baseLiteratureNumber=spnu151&fileType=pdf   (Search 'ecc' for the command line options to inject errros).

One of my colleagues has tried the feature and used this linker command file - at minimum I think you will need the device specific information that is in the ECC {} section.   The RM46 settings should be the same as the TMS570LS313x settings in this ECC {} section.

/*----------------------------------------------------------------------------*/
/* TMS570LS313xFlashLnk.cmd                                                 */
/*                                                                            */
/* (c) Texas Instruments 2011, All rights reserved.                           */
/*                                                                            */

/* USER CODE BEGIN (0) */
/* USER CODE END */


/*----------------------------------------------------------------------------*/
/* Linker Settings                                                            */
--retain="*(.intvecs)"
-stack=0x1000

/*----------------------------------------------------------------------------*/
/* Memory Map                                                                 */
MEMORY{
    VECTORS (X)  : org = 0x00000000 len = 0x00000020
#if defined( __TI_COMPILER_VERSION__ ) && ( __TI_COMPILER_VERSION__ >= 5001000)
                                     vfill = 0xffffffff
#endif
    FLASH0  (RX) : org = 0x00000020 len = 0x0017FFE0
#if defined( __TI_COMPILER_VERSION__ ) && ( __TI_COMPILER_VERSION__ >= 5001000)
                                     vfill = 0xffffffff
#endif
    FLASH1  (RX) : org = 0x00180000 len = 0x00180000
#if defined( __TI_COMPILER_VERSION__ ) && ( __TI_COMPILER_VERSION__ >= 5001000)
                                     vfill = 0xffffffff
                                       
    VECTORS_ECC  : org = 0xf0400000  len = 0x00000004  ecc = { input_range = VECTORS,
                                                               algorithm   = eccalgo,
                                                               fill        = true }
    FLASH0_ECC   : org = 0xf0400004  len = 0x0002FFFC  ecc = { input_range = FLASH0,
                                                               algorithm   = eccalgo,
                                                               fill        = true }
    FLASH1_ECC   : org = 0xf0430000  len = 0x00030000  ecc = { input_range = FLASH1,
                                                               algorithm   = eccalgo,
                                                               fill        = true }
#endif

    STACKS  (RW) : origin=0x08000000 length=0x00001300
    RAM     (RW) : origin=0x08001300 length=0x0003ED00
}

#if defined( __TI_COMPILER_VERSION__ ) && ( __TI_COMPILER_VERSION__ >= 5001000)
ECC
{
   eccalgo : address_mask = 0x003ffff8
             hamming_mask = R4
             parity_mask  = 0x0C
             mirroring    = F021
}
#endif

/*----------------------------------------------------------------------------*/
/* Section Configuration                                                      */
SECTIONS{
    .intvecs : {} > VECTORS
    .text    : {} > FLASH0 | FLASH1
    .const   : {} > FLASH0 | FLASH1
    .cinit   : {} > FLASH0 | FLASH1
    .pinit   : {} > FLASH0 | FLASH1
    .bss     : {} > RAM
    .data    : {} > RAM
    .stack   : {} > STACKS
}
/*----------------------------------------------------------------------------*/

Andy,

I think you need to let HalCoGen go ahead and generate the sys_link but make your own copy with a different name, customize it, and change your CCS project so it ignores the HalCoGen generated file.

I'll submit a CQ enhancment request to look at adjusting this.

With the compiler header files the normal trick is to put an '#if 0' in the user code section before (e.x. (1) and an   '#endif' in the user code section after (ex..(3)) where the user code numbers are the ones in the sys_link.cmd file.  And then after the #endif in the section 3 you would copy/paste an entire new Memory{} construct.  But I don't think the preprocessor works on linker command files.