Compiler/TM4C1294NCPDT: Flash memory read protection

Adding a few more details. You partition the flash into the readable and the execute only portions in the link command file. Here is a sample that I did.

/* System memory map */

MEMORY
{
    /* Application stored in and executes from internal flash */
    FLASH (RX) : origin = APP_BASE, length = 0x00010000
    FLASH2 (X) : origin = 0x00010000, length = 0x00030000
    /* Application uses internal RAM for data */
    SRAM (RWX) : origin = 0x20000000, length = 0x00008000
}

/* Section allocation in memory */

SECTIONS
{
    .intvecs:   > APP_BASE
    .libtext:
    {
    	driverlib.lib<*.obj>(.text)
    	rtsv7M4_T_le_v4SPD16_eabi.lib<*.obj>(.text)
    }    > FLASH
    .text   :   > FLASH2
    .const  :   > FLASH
    .cinit  :   > FLASH
    .pinit  :   > FLASH
    .init_array : > FLASH

    .vtable :   > RAM_BASE
    .data   :   > SRAM
    .bss    :   > SRAM
    .sysmem :   > SRAM
    .stack  :   > SRAM
}

__STACK_TOP = __stack + 256;

In lines 6 and 7 I broke the flash into two memory blocks. The readable part I left named FLASH and the execute only part I gave the name of FLASH2. In the sections directive I changed the .text section to point to FLASH2 (line 22). Now as Amit mentioned, you must compile the code so it does not embedded constants in the .text section. If you don't want to recompile the libraries with that option, the .text section from the libraries must be linked into the readable flash. My code referenced two libraries. I redirected the .text sections from those two libraries into FLASH in lines 17 through 21.

Disallow embedding constants in your runtime code by changing the project settings as shown below:

The distinction between the memory regions FLASH and FLASH2 is that for the range defined as FLASH2 you will program the Flash Memory Protection register bits to make that memory Execute Only. Since you don't know how much Execute Only flash you need and how much readable flash you need until your code development is complete here is another way to link your file:

#define APP_BASE 0x00000000
#define RAM_BASE 0x20000000

/* System memory map */

MEMORY
{
    /* Application stored in and executes from internal flash */
    FLASH (RX) : origin = APP_BASE, length = 0x00040000
    /* Application uses internal RAM for data */
    SRAM (RWX) : origin = 0x20000000, length = 0x00008000
}

/* Section allocation in memory */

SECTIONS
{
    .intvecs:   > APP_BASE
    .libtext:
    {
    	driverlib.lib<*.obj>(.text)
    	rtsv7M4_T_le_v4SPD16_eabi.lib<*.obj>(.text)
    }    > FLASH
    .text   :   > FLASH palign = 2048, fill = 0xffffffff
    .const  :   > FLASH
    .cinit  :   > FLASH
    .pinit  :   > FLASH
    .init_array : > FLASH

    .vtable :   > RAM_BASE
    .data   :   > SRAM
    .bss    :   > SRAM
    .sysmem :   > SRAM
    .stack  :   > SRAM
}

__STACK_TOP = __stack + 256;

In this link command file, all 1MB of flash is represented by FLASH. Note that in line 24 I added the key words "palign" and "fill". Since the Execute Only portion of the flash must be contained in some number of 2KB segments, I used "palign = 2048" to align this output section to a 2KB boundary, and pad to the end of a 2KB boundary. The "fill" keyword says to use 0xffffffff as the fill value for the padding. The padding prevents the linker from packing any other code that may need read access onto the end of my Execute Only code.

Once my code development is complete, I can look at the .map file generated by the linker and see which 2KB section of flash to convert to Execute Only. If I want to put the Execute Only section in a particular place, such as at the top end of the flash, then I could break the FLASH memory directive into FLASH and FLASH2 like I did before, but now I know the exact sizes needed.