TMS320F28379D: DELAY_US routine jumps to ILLEGAL_ISR when app running in FLASH

Adria Perez Martinez

Part Number: TMS320F28379D
Other Parts Discussed in Thread: CONTROLSUITE, C2000WARE

Hello,

When I execute "DELAY_US()" in app running on FLASH, then code immediately jumps to ILLEGAL_ISR(). Instead, when I execute "DELAY_US()" in app running on RAM it works OK. I would like to be able to call "DELAY_US()" in app running on FLASH and make it work properly. I am using default linker command files (provided in controlSUITE).

Taking a look into linker command file, this routine is loaded into FLASH but executed in RAM.

Can anybody help please?

Thanks in advance!

Best regards,

Adria

over 6 years ago

0 Harsh Singh over 6 years ago

TI__Expert 3795 points

Hi Adria,

Can you please refer to the C2000Ware Package?

Which project are you trying to run?

Thanks and Regards
Harshmeet

0 Adria Perez Martinez over 6 years ago in reply to Harsh Singh

Expert 1280 points

Hello Harshmeet,

Harshmeet Singh said:

Can you please refer to the C2000Ware Package?

I use controlSUITE package which contains C2000Ware. Routine "DELAY_US()" is in "F2837xD_usDelay.asm" (which can be found in path "ti/controlSUITE/device_support/F2837xD/v210/F2837xD_common/source/"). As linker command file I use "2837xD_FLASH_lnk_cpu1.cmd" (which can be found in path "ti/controlSUITE/device_support/F2837xD/v210/F2837xD_common/cmd/").

Harshmeet Singh said:

Which project are you trying to run?

I run my own project, for example, containing code below:

void main(void)
{
    InitSysCtrl();
    InitGpio();
    DINT;
    IER = 0x0000;
    IFR = 0x0000;
    InitPieCtrl();
    InitPieVectTable();
    EnableInterrupts();
    DELAY_US(1000000); // Delay 1 second
    while(1)
    {
        /* Do Nothing */
    }
}

This code perfectly works on RAM. Instead, when run on FLASH and reaches line "DELAY_US(1000000); // Delay 1 second" it jumps to ILLEGAL_ISR().

Best regards,

Adria

0 ashutosh bhatt over 6 years ago

Expert 1490 points

Could you please share the screenshots of the project and your program. It seems that some issue with your linker file.

Ashutosh

0 Harsh Singh over 6 years ago in reply to Harsh Singh

TI__Expert 3795 points

Hi Adria,

Some points here:

1. Are you using a flash linker command file?

2. There is a define _FLASH which copies time critical code and Flash setup code to RAM.

The DELAY_US() will be copied to RAM and you can run it in flash. It is in the F2837xD_SysCtrl,c File in the initSysCtrl Routine.

Please check if you are doing these.

Thanks and Regards

Harshmeet Singh

0 Adria Perez Martinez over 6 years ago in reply to Harsh Singh

Expert 1280 points

Hello,

Please find below screenshots of my project project properties where you can see how _FLASH has been defined:

Best regards,

Adria

0 Adria Perez Martinez over 6 years ago in reply to Adria Perez Martinez

Expert 1280 points

Find below project properties showing how flash linker command file I said is being used:

0 Adria Perez Martinez over 6 years ago in reply to Adria Perez Martinez

Expert 1280 points

Find below content of the default flash linker command file I use (found in ""):

"

MEMORY
{
PAGE 0 : /* Program Memory */
/* Memory (RAM/FLASH) blocks can be moved to PAGE1 for data allocation */
/* BEGIN is used for the "boot to Flash" bootloader mode */

BEGIN : origin = 0x080000, length = 0x000002
RAMM0 : origin = 0x000122, length = 0x0002DE
RAMD0 : origin = 0x00B000, length = 0x000800
RAMLS0 : origin = 0x008000, length = 0x000800
RAMLS1 : origin = 0x008800, length = 0x000800
RAMLS2 : origin = 0x009000, length = 0x000800
RAMLS3 : origin = 0x009800, length = 0x000800
RAMLS4 : origin = 0x00A000, length = 0x000800
RAMGS14 : origin = 0x01A000, length = 0x001000 /* Only Available on F28379D, F28377D, F28375D devices. Remove line on other devices. */
RAMGS15 : origin = 0x01B000, length = 0x001000 /* Only Available on F28379D, F28377D, F28375D devices. Remove line on other devices. */
RESET : origin = 0x3FFFC0, length = 0x000002

/* Flash sectors */
FLASHA : origin = 0x080002, length = 0x001FFE /* on-chip Flash */
FLASHB : origin = 0x082000, length = 0x002000 /* on-chip Flash */
FLASHC : origin = 0x084000, length = 0x002000 /* on-chip Flash */
FLASHD : origin = 0x086000, length = 0x002000 /* on-chip Flash */
FLASHE : origin = 0x088000, length = 0x008000 /* on-chip Flash */
FLASHF : origin = 0x090000, length = 0x008000 /* on-chip Flash */
FLASHG : origin = 0x098000, length = 0x008000 /* on-chip Flash */
FLASHH : origin = 0x0A0000, length = 0x008000 /* on-chip Flash */
FLASHI : origin = 0x0A8000, length = 0x008000 /* on-chip Flash */
FLASHJ : origin = 0x0B0000, length = 0x008000 /* on-chip Flash */
FLASHK : origin = 0x0B8000, length = 0x002000 /* on-chip Flash */
FLASHL : origin = 0x0BA000, length = 0x002000 /* on-chip Flash */
FLASHM : origin = 0x0BC000, length = 0x002000 /* on-chip Flash */
FLASHN : origin = 0x0BE000, length = 0x002000 /* on-chip Flash */

PAGE 1 : /* Data Memory */
/* Memory (RAM/FLASH) blocks can be moved to PAGE0 for program allocation */

BOOT_RSVD : origin = 0x000002, length = 0x000120 /* Part of M0, BOOT rom will use this for stack */
RAMM1 : origin = 0x000400, length = 0x000400 /* on-chip RAM block M1 */
RAMD1 : origin = 0x00B800, length = 0x000800

RAMLS5 : origin = 0x00A800, length = 0x000800

RAMGS0 : origin = 0x00C000, length = 0x001000
RAMGS1 : origin = 0x00D000, length = 0x001000
RAMGS2 : origin = 0x00E000, length = 0x001000
RAMGS3 : origin = 0x00F000, length = 0x001000
RAMGS4 : origin = 0x010000, length = 0x001000
RAMGS5 : origin = 0x011000, length = 0x001000
RAMGS6 : origin = 0x012000, length = 0x001000
RAMGS7 : origin = 0x013000, length = 0x001000
RAMGS8 : origin = 0x014000, length = 0x001000
RAMGS9 : origin = 0x015000, length = 0x001000
RAMGS10 : origin = 0x016000, length = 0x001000
RAMGS11 : origin = 0x017000, length = 0x001000
RAMGS12 : origin = 0x018000, length = 0x001000 /* Only Available on F28379D, F28377D, F28375D devices. Remove line on other devices. */
RAMGS13 : origin = 0x019000, length = 0x001000 /* Only Available on F28379D, F28377D, F28375D devices. Remove line on other devices. */

CPU2TOCPU1RAM : origin = 0x03F800, length = 0x000400
CPU1TOCPU2RAM : origin = 0x03FC00, length = 0x000400
}

SECTIONS
{
/* Allocate program areas: */
.cinit : > FLASHB PAGE = 0, ALIGN(4)
.pinit : > FLASHB, PAGE = 0, ALIGN(4)
.text : >> FLASHB | FLASHC | FLASHD | FLASHE PAGE = 0, ALIGN(4)
codestart : > BEGIN PAGE = 0, ALIGN(4)

/* Allocate uninitalized data sections: */
.stack : > RAMM1 PAGE = 1
.ebss : >> RAMLS5 | RAMGS0 | RAMGS1 PAGE = 1
.esysmem : > RAMLS5 PAGE = 1

/* Initalized sections go in Flash */
.econst : >> FLASHF | FLASHG | FLASHH PAGE = 0, ALIGN(4)
.switch : > FLASHB PAGE = 0, ALIGN(4)

.reset : > RESET, PAGE = 0, TYPE = DSECT /* not used, */

Filter_RegsFile : > RAMGS0, PAGE = 1

SHARERAMGS0 : > RAMGS0, PAGE = 1
SHARERAMGS1 : > RAMGS1, PAGE = 1
ramgs0 : > RAMGS0, PAGE = 1
ramgs1 : > RAMGS1, PAGE = 1

#ifdef __TI_COMPILER_VERSION__
#if __TI_COMPILER_VERSION__ >= 15009000
.TI.ramfunc : {} LOAD = FLASHD,
RUN = RAMLS0 | RAMLS1 | RAMLS2 |RAMLS3,
LOAD_START(_RamfuncsLoadStart),
LOAD_SIZE(_RamfuncsLoadSize),
LOAD_END(_RamfuncsLoadEnd),
RUN_START(_RamfuncsRunStart),
RUN_SIZE(_RamfuncsRunSize),
RUN_END(_RamfuncsRunEnd),
PAGE = 0, ALIGN(4)
#else
ramfuncs : LOAD = FLASHD,
RUN = RAMLS0 | RAMLS1 | RAMLS2 |RAMLS3,
LOAD_START(_RamfuncsLoadStart),
LOAD_SIZE(_RamfuncsLoadSize),
LOAD_END(_RamfuncsLoadEnd),
RUN_START(_RamfuncsRunStart),
RUN_SIZE(_RamfuncsRunSize),
RUN_END(_RamfuncsRunEnd),
PAGE = 0, ALIGN(4)
#endif
#endif

/* The following section definitions are required when using the IPC API Drivers */
GROUP : > CPU1TOCPU2RAM, PAGE = 1
{
PUTBUFFER
PUTWRITEIDX
GETREADIDX
}

GROUP : > CPU2TOCPU1RAM, PAGE = 1
{
GETBUFFER : TYPE = DSECT
GETWRITEIDX : TYPE = DSECT
PUTREADIDX : TYPE = DSECT
}

/* The following section definition are for SDFM examples */
Filter1_RegsFile : > RAMGS1, PAGE = 1, fill=0x1111
Filter2_RegsFile : > RAMGS2, PAGE = 1, fill=0x2222
Filter3_RegsFile : > RAMGS3, PAGE = 1, fill=0x3333
Filter4_RegsFile : > RAMGS4, PAGE = 1, fill=0x4444
Difference_RegsFile : >RAMGS5, PAGE = 1, fill=0x3333
}

/*
//===========================================================================
// End of file.
//===========================================================================
*/

"

0 Adria Perez Martinez over 6 years ago in reply to Adria Perez Martinez

Expert 1280 points

To verify that _FLASH define is being defined, I have checked, through the JTAG debugger, that "DELAY_US()" is being copied from FLASH to RAM within file "ti/controlSUITE/device_support/F2837xD/v210/F2837xD_common/source/F2837xD_SysCtrl.c".

0 Adria Perez Martinez over 6 years ago in reply to Adria Perez Martinez

Expert 1280 points

Hello,

I already found the issue!

It was because I was compiling with compiler version 6.4.6 with controlSUITE version 210 and it was causing an incompatibility between section ".TI.ramfunc" (the new way) and "ramfuncs" (the old way).

I think a preprocessor directive is missing in file F2837xD_CodeStartBranch.asm checking for compiler version in order to define the proper section. It is perfectly done in the linker command file, but just forgotten in F2837xD_CodeStartBranch.asm file.

The solution is simply to change compiler to version 8.1.3.

Best regards,

Adria

C2000™︎ microcontrollers

C2000 microcontrollers forum

TMS320F28379D: DELAY_US routine jumps to ILLEGAL_ISR when app running in FLASH