Linux/PROCESSOR-SDK-AM335X: Yocto configuration

Hello Santhana,

santhana kumar s said:

fms-debug-image-sfms.tar.xz --> link name i.e. debug-image.tar.xz <part> -rootfs-image-<board>.tar.xz --> link name i.e. release-image.tar.xz fms-debug-image-sfms.ubi --> link name i.e. debug-image.ubi fms-rootfs-image-sfms.ubi --> link name i.e. release-image.ubi

You can see how the new image symlincs are created here by the create_symlinks function in <tisdk>/sources/oe-core/meta/classes/image.bbclass.

#
# Create symlinks to the newly created image
#
python create_symlinks() {

    deploy_dir = d.getVar('IMGDEPLOYDIR')
    img_name = d.getVar('IMAGE_NAME')
    link_name = d.getVar('IMAGE_LINK_NAME')
    manifest_name = d.getVar('IMAGE_MANIFEST')
    taskname = d.getVar("BB_CURRENTTASK")
    subimages = (d.getVarFlag("do_" + taskname, 'subimages', False) or "").split()
    imgsuffix = d.getVarFlag("do_" + taskname, 'imgsuffix') or d.expand("${IMAGE_NAME_SUFFIX}.")

    if not link_name:
        return
    for type in subimages:
        dst = os.path.join(deploy_dir, link_name + "." + type)
        src = img_name + imgsuffix + type
        if os.path.exists(os.path.join(deploy_dir, src)):
            bb.note("Creating symlink: %s -> %s" % (dst, src))
            if os.path.islink(dst):
                os.remove(dst)
            os.symlink(src, dst)
        else:
            bb.note("Skipping symlink, source does not exist: %s -> %s" % (dst, src))
}

santhana kumar s said:

zImage-sfms- <board-name>.dtb --> link name i.e. <our-board-name>.dtb

You can see how the dtb symlincs are created here in <tisdk>/sources/oe-core/meta/classes/kernel-devicetree.bbclass file.

do_deploy_append() {
    for DTB in ${KERNEL_DEVICETREE}; do
        DTB=`normalize_dtb "${DTB}"`
        DTB_EXT=${DTB##*.}
        DTB_BASE_NAME=`basename ${DTB} ."${DTB_EXT}"`
        for type in ${KERNEL_IMAGETYPE_FOR_MAKE}; do
            base_name=${type}"-"${KERNEL_IMAGE_BASE_NAME}
            symlink_name=${type}"-"${KERNEL_IMAGE_SYMLINK_NAME}
            DTB_NAME=`echo ${base_name} | sed "s/${MACHINE}/${DTB_BASE_NAME}/g"`
            DTB_SYMLINK_NAME=`echo ${symlink_name} | sed "s/${MACHINE}/${DTB_BASE_NAME}/g"`
            DTB_PATH=`get_real_dtb_path_in_kernel "${DTB}"`
            install -d ${DEPLOYDIR}
            install -m 0644 ${DTB_PATH} ${DEPLOYDIR}/${DTB_NAME}.${DTB_EXT}
            ln -sf ${DTB_NAME}.${DTB_EXT} ${DEPLOYDIR}/${DTB_SYMLINK_NAME}.${DTB_EXT}
            ln -sf ${DTB_NAME}.${DTB_EXT} ${DEPLOYDIR}/${DTB_BASE_NAME}.${DTB_EXT}

            if [ "$type" = "zImage" ] && [ "${KERNEL_DEVICETREE_BUNDLE}" = "1" ]; then
                cat ${DEPLOYDIR}/$type \
                    ${DEPLOYDIR}/${DTB_NAME}.${DTB_EXT} \
                    > ${DEPLOYDIR}/${DTB_NAME}.${DTB_EXT}.bin
                ln -sf ${DTB_NAME}.${DTB_EXT}.bin ${DEPLOYDIR}/$type-${DTB_BASE_NAME}.${DTB_EXT}.bin

                if [ -e "${KERNEL_OUTPUT_DIR}/${type}.initramfs" ]; then
                    cat ${KERNEL_OUTPUT_DIR}/${type}.initramfs \
                        ${DEPLOYDIR}/${DTB_NAME}.${DTB_EXT} \
                        > ${DEPLOYDIR}/${type}-${INITRAMFS_BASE_NAME}-${DTB_BASE_NAME}.${DTB_EXT}.bin
                    ln -sf ${type}-${INITRAMFS_BASE_NAME}-${DTB_BASE_NAME}.${DTB_EXT}.bin \
                           ${DEPLOYDIR}/${type}-initramfs-${DTB_BASE_NAME}.${DTB_EXT}-${MACHINE}.bin
                fi
            fi
        done
    done
}

Edit these files and add the extra name in the way you want.

Best regards,
Kemal